Evernoteで複数選択したノートのタイトルに単語を追加するAppleScript

2013-06-22にQiitaに投稿した記事のアーカイブです。本文中のリンクは動作しないことがあります。

--Append Word to Evernote Notes Title
--Copyright © 2013 armorik83

on run
	tell application "Evernote"
		activate
		
		set selectedNotes to selection
		
		set n to count selectedNotes
		set defaultAnswer to (title of item 1 of selectedNotes)
		
		if selectedNotes is not {} then
			display dialog "Enter the word you want to append." default answer "" buttons {"Cancel", "Append Before", "Append After"} default button 3
			set {text returned:appendWord, button returned:clickedButton} to result
			if clickedButton is "Append Before" then
				
				repeat with i from 1 to n
					set theName to (title of item i of selectedNotes)
					set result to appendWord & theName
					set title of item i of selectedNotes to result as text
				end repeat
				
			else if clickedButton is "Append After" then
				
				repeat with i from 1 to n
					set theName to (title of item i of selectedNotes)
					set result to theName & appendWord
					set title of item i of selectedNotes to result as text
				end repeat
				
			end if
			
		else
			activate
			beep 1
			display dialog "Notes has not been selected." buttons {"OK"} default button 1
		end if
		
	end tell
end run

• Evernoteアプリケーション内でノートを複数選択した後スクリプトを起動し、追加したい文字列を入力しボタンを選択することで、タイトルに文字列を一括して追加できます。
• "Append Before"を選択すると先頭に追加、"Append After"を選択すると末尾に追加します。
• 空白の入力処理は行なっていませんので、あらかじめ必要に応じて空白なども入力してください。
• 大きな問題となるような処理はしていないはずですが、使用における損失に関する責任は負いかねます。

追加に失敗してしまった場合は、こちらのAppleScriptで検索・置換を行うことで対処できます。