Evernoteで複数選択したノートのタイトルを置換するAppleScript

2 min read読了の目安(約1600字

2013-03-18 にQiitaに投稿した記事のアーカイブです。本文中のリンクは動作しないことがあります。

--Replace Evernote Notes Title
--Copyright © 2013 armorik83
on run
	tell application "Evernote"
		activate
		set selectedNotes to selection
		set n to count selectedNotes
		set defaultAnswer to (title of item 1 of selectedNotes)
		if selectedNotes is not {} then
			display dialog "Enter a search string." default answer defaultAnswer buttons {"Cancel", "OK"} default button 2
			set {text returned:findWord, button returned:clickedButton} to result
			if (findWord is not "") and (clickedButton is "OK") then
				display dialog "Enter the replacement string." default answer findWord buttons {"Cancel", "OK"} default button 2
				set {text returned:replaceWord, button returned:clickedButton} to result
				if clickedButton is "OK" then
					set saveDelimiter to AppleScript's text item delimiters
					repeat with i from 1 to n
						set theName to (title of item i of selectedNotes)
						set AppleScript's text item delimiters to findWord
						set theName to every text item of theName
						set AppleScript's text item delimiters to replaceWord
						set title of item i of selectedNotes to theName as text
					end repeat
					set AppleScript's text item delimiters to saveDelimiter
				end if
			end if
		else
			activate
			beep 1
			display dialog "Notes has not been selected." buttons {"OK"} default button 1
		end if
	end tell
end run
  • Evernoteアプリケーション内でノートを複数選択した後スクリプトを起動し、置換前の文字列、置換後の文字列を入力することで、ノートのタイトルを一括して置換できます。
  • 大きな問題となるような処理はしていないはずですが、使用における損失に関する責任は負いかねます。

こちらのAppleSctriptで、複数ノートのタイトルに対する文字列の一括追加が行えます。