🌈

そろそろShaderをやるパート49 リムライト

2021/12/05に公開約3,000字

そろそろShaderをやります

そろそろShaderをやります。そろそろShaderをやりたいからです。
パート100までダラダラ頑張ります。10年かかってもいいのでやります。
100記事分くらい学べば私レベルの初心者でもまあまあ理解できるかなと思っています。

という感じでやってます。

※初心者がメモレベルで記録するので
 技術記事としてはお力になれないかもしれません。

下準備

下記参考
そろそろShaderをやるパート1 Unite 2017の動画を見る(基礎知識~フラグメントシェーダーで色を変える)

デモ

リムライトってのはこんなやつです。

Rimは"縁"のような意味らしく、縁の部分が光っている、それがリムライトです。

Shaderサンプル

Shader "Custom/Rim"
{
    Properties
    {
        _TintColor("Tint Color", Color) = (0,0.5,1,1)
        _RimColor("Rim Color", Color) = (0,1,1,1)
        _RimPower("Rim Power", Range(0,1)) = 0.4
    }

    Category
    {
        Tags
        {
            "Queue" = "Transparent"
            "RenderType" = "Transparent"
        }
        Blend SrcAlpha OneMinusSrcAlpha

        SubShader
        {
            Pass
            {
               ZWrite On
               ColorMask 0
            }

            Pass
            {
                CGPROGRAM
                #pragma vertex vert
                #pragma fragment frag

                #include "UnityCG.cginc"

                float4 _TintColor;
                float4 _RimColor;
                float _RimPower;

                struct appdata_t
                {
                    float4 vertex : POSITION;
                    float2 uv : TEXCOORD0;
                    float3 normal : NORMAL;
                };

                struct v2f
                {
                    float4 vertex : SV_POSITION;
                    float2 uv : TEXCOORD0;
                    float3 world_pos : TEXCOORD1;
                    float3 normalDir : TEXCOORD2;
                };

                v2f vert(appdata_t v)
                {
                    v2f o;

                    o.vertex = UnityObjectToClipPos(v.vertex);
                    o.uv = v.uv;
                    o.world_pos = mul(unity_ObjectToWorld, v.vertex).xyz;
                    //法線を取得
                    o.normalDir = UnityObjectToWorldNormal(v.normal);
                    return o;
                }

                fixed4 frag(v2f i) : SV_Target
                {
                    //カメラのベクトルを計算
                    float3 viewDirection = normalize(_WorldSpaceCameraPos.xyz - i.world_pos.xyz);
                    //法線とカメラのベクトルの内積を計算し、補間値を算出
                    half rim = 1.0 - saturate(dot(viewDirection, i.normalDir));
                    //補間値で塗分け
                    float4 col = lerp(_TintColor, _RimColor, rim * _RimPower);
                    return col;
                }
                ENDCG
            }
        }
    }
}

saturateは引数を0~1の範囲で納めてくれます。
法線とカメラのベクトルをsaturateで0~1にまるめて、リムライトの塗分けの補間値を計算しています。

法線とカメラのベクトルが直行している場合、内積は0を返し、同じ方向の場合1を返します。
【参考リンク】:そろそろShaderをやるパート31 内積を使う

下記記事で非常にわかりやすく図解されています。
【参考リンク】:リムライト

Discussion

ログインするとコメントできます