M5用ペンホルダーの作成
持ち歩き手帳にペンホルダーを付けたいと思ったものの, 既製品では決定的なものがなかったため, クリアファイルを加工して自作した.
完成した型紙
(p.1 が HI-TEC-C Colete(2色)用で p.2 が uni-ball one P 用です. 短編綴じ両面印刷にすると無駄なく印刷できます.)
0. 概要
持ち歩き予定のペン(HI-TEC-C Coleto or uni-ball one P)に合わせてペンホルダーを自作する. 完成版のイメージは以下のとおり(透明なクリアファイルで作ったので見えにくいですが, ペン全体を包むようなペンホルダーになってます).
HI-TEC-C Coleto:
uni-ball one P
1. 作成の経緯
以前の記事で uni-ball one P の限定色(スチールグレー)を買えなかったと書いたところ, 先日たまたまイオンで見かけて思わず買ってしまった. それならついでに手帳につけるペンホルダーもあった方がいいよね, ということでいろいろ検討してみた.
まずは手帳に合わせて純正の PLOTTER本革ペンホルダー. おしゃれだしなにより純正品ということで安心感があるものの, 自分にはおしゃれすぎるかな. あとホルダーが革だと入れられるペンに制約がありそうだし, クリップを掛けるとクリップが開いて傷みそう.
次にネットで評判が良かったASHFORDルガードストレッチペンホルダー. ホルダー部分は皮製に見えて裏はゴムになっているらしい. 正直これでいっか, と思って中もしていたものの, 残念ながらいつ見ても品切れ. あちこちに多少在庫はあるものの欲しかった黒は在庫切れ.
あと uni-ball one P 限定だけど文具王工作室のホルダー. これもシンプルでいいんだけど, 厚みが 1mm もあるのがなぁ. M5手帳の 1mm は貴重すぎてペンホルダーに使うには躊躇します.
というわけで, 決定打にかける感じだったので, とりあえず自分で作ることにしました. いろいろ検索してみるとこちらのYoutube動画とか参考になりそうだったので, 雰囲気はこれを真似することにしました.
2. 道具類の準備
作成に使ったものはこんな感じです.
左から
- はさみ(最近話題のやつで確かにすごく切りやすいです.)
- マステとマステカッター(きれいに仕上げるこつはまめにマステで固定することかな. マステカッターはちゃんと切れるものがいいです. コクヨ カルカット)
- 手帳(プロッターM5)
- uni-ball one P
- スチール定規(カッターで切るとき用. スチール製なのでメモリが比較的正確.)
- HI-TEC-C Coleto 2色
- ノギス付きの定規(プラスチック製なので若干精度に不安があるものの, お手軽に使えるのは良い. 厚みを測れる定規)
- カッター(細かい作業にはやっぱり細工用が使いやすい.)
- 千枚通し(たぶん百均で買ったもの. 虫ピンでもOK. 切り込みの端にあらかじめ穴をあけておくときれいに仕上がる.)
- 直径 3mm の1穴パンチ(裏のゴミ貯めのカバーを外して穴を覗きながら使う. 3mm だとリング径ギリギリなので, 穴の位置が正確じゃないとページをめくるときに引っかかる. これの 4mm が欲しいけどまだない(多分今後もない). 中華製で 4mm の直径のパンチを見つけたけどレビューを見ると品質にあたりはずれがありそうなので怖くて手をだせない.)
- カッティングマット(これも百均だったと思う.)
写真に写ってないけど使わなくなった名刺の束. 千枚通しで穴をあけるときの下敷きに使った. あと, 当然材料としてのクリアファイル. 私は前に何かを作るのに使ってそこらへんに放置していた切れ端を使ったのでちょっと汚い & 文字が入っちゃってる. 無地の新品を使った方が無難だと思う.
3. 型紙
3.1 HI-TEC-C Coleto 用
- 左側が通常のリフィル部分
- 右側に HI-TEC-C Colete の軸の周の長さ分を追加(ホルダー部分)
- 軸の周の長さぴったりだときつすぎるので, 直径+1mm で作成(週の長さだと +3.14mm)
- くるっと丸めて差し込めるように差し込む部分と差込口を作る
- 小さな黒い点は千枚通し(もしくは虫ピン等)で穴をあける部分
- 真ん中の破線の長方形は切り抜いてマステでクリアファイルに型紙を固定するための穴を表す
3.2 uni-ball one P 用
- 基本的なつくりは HI-TEC-C Coleto と同じ
- 軸が太いのでホルダー部分の幅が広くなっている
- HI-TEC-C Coleto と比較してクリップが浅いので, クリップを差し込むための溝を作ってある(深さ20mm)
- 溝はホルダー部分の中央に配置しているが, 実際の使用状況(手帳の一番右端にいれて使う, など)によっては少しリフィル部分に寄せるなどの調整を行ってもいいかもしれない.
3.3 MetaPost コード
プログラムの概要は以下のとおり.
prologues := 3;
outputtemplate := "%j/%2c.%o";
outputformat := "svg";
% outputformat := "png";
u:=1mm;
def penholder(expr s) =
% pen specific part
if s="coleto":
% ...
elseif s="onep":
% ...
fi
% common part
% ...
enddef; % penholder
beginfig(1);
penholder("coleto");
currentpicture := currentpicture scaled (96/72);
endfig;
beginfig(2);
penholder("onep");
currentpicture := currentpicture scaled (96/72);
endfig;
end
- HI-TEC-C Coleto と uni-ball one P でほとんど同じなので, マクロにして再利用可能にしている.
- 両者で微妙に違う部分は種類を表す文字列を引数にして, それをもとに内部で分岐させている.
プログラムの全体像は以下のとおり.
型紙のプログラム
prologues := 3;
outputtemplate := "%j/%2c.%o";
outputformat := "svg";
% outputformat := "png";
u:=1mm;
def penholder(expr s) =
% pen specific part
if s="coleto":
% ホルダーの直径に少し余裕を持たせる
x:=3.14*(11u+u); % Hi-Tech-C Coleto
label.lrt(btex HI-TEC-C COLETO / diameter: 11.0mm, circumference: 34.54mm etex,(-10u,105u+10u));
elseif s="onep":
% ホルダーの直径に少し余裕を持たせる
x = 3.14*(13.7u+u); % uni-ball one P
label.lrt(btex uni-ball one P / diameter: 13.7mm, circumference: 43.018mm etex,(-10u,105u+10u));
% only for uni-ball one P
% uni-ball one P はクリップを少し差し込まないとM5手帳からはみ出る
xx := 5.2u; % クリップの幅
yy := 20u; % クリップの深さ
draw (62u+(x-xx)/2,105u)
--(62u+(x-xx)/2,105u-yy)
--(62u+(x-xx)/2+xx,105u-yy)
--(62u+(x-xx)/2+xx,105u);
pickup pencircle scaled u;
drawdot (62u+(x-xx)/2,105u-yy);
drawdot (62u+(x-xx)/2+xx,105u-yy);
pickup defaultpen;
fi
% common part
draw (62u,0)--(0,0)--(0,105u)--(62u,105u);
draw (62u,105u)--(62u,0) dashed evenly;
draw (62u,0)--(62u+x,0);
draw (62u,105u)--(62u+x,105u);
draw (62u+x,0)
--(62u+x, 9.5u)
--(62u+x+10u,14.5u)
--(62u+x+10u,14.5u+19u)
--(62u+x, 14.5u+19u+5u)
--(62u+x, 14.5u+19u+5u+28u)
--(62u+x+10u,14.5u+19u+5u+28u+5u)
--(62u+x+10u,14.5u+19u+5u+28u+5u+19u)
--(62u+x, 14.5u+19u+5u+28u+5u+19u+5u)
--(62u+x, 105u); % =...+9.5u (y座標の一致を確認)
% リングホール
pickup pencircle scaled 2u;
for i=0 upto 4:
drawdot (4.5u,14.5u+i*19u);
endfor
pickup defaultpen;
% 差し込み口
draw (62u,14.5u)--(62u,14.5u+19u);
draw (62u,105u-14.5u)--(62u,105u-14.5u-19u);
pickup pencircle scaled u;
drawdot (62u,14.5u);
drawdot (62u,14.5u+19u);
drawdot (62u,105u-14.5u);
drawdot (62u,105u-14.5u-19u);
pickup defaultpen;
% 差し込む部分の切れ込み
draw (62u+x,14.5u-5u)--(62u+x,14.5u);
draw (62u+x,14.5u+19u)--(62u+x,14.5u+19u+5u);
draw (62u+x,105u-14.5u+5u)--(62u+x,105u-14.5u);
draw (62u+x,105u-14.5u-19u)--(62u+x,105u-14.5u-19u-5u);
pickup pencircle scaled u;
drawdot (62u+x,14.5u);
drawdot (62u+x,14.5u+19u);
drawdot (62u+x,105u-14.5u);
drawdot (62u+x,105u-14.5u-19u);
pickup defaultpen;
% マステ用の内側の穴
draw (20u,20u)--(40u,20u)
--(40u,85u)--(20u,85u)
--cycle dashed evenly;
draw (62u+x/3,20u)--(62u+2x/3,20u)
--(62u+2x/3,80u)--(62u+x/3,80u)
--cycle dashed evenly;
enddef; % penholder
beginfig(1);
penholder("coleto");
currentpicture := currentpicture scaled (96/72);
endfig;
beginfig(2);
penholder("onep");
currentpicture := currentpicture scaled (96/72);
endfig;
end
4. 組み立て
組み立て手順:
- 型紙を印刷して適当な大きさに切り抜く(内側の窓も切り抜いておく)
- クリアファイルにマステで固定する. (クリアファイルは最初に接着されている部分を切り離し, 開いておくと作業しやすい.)
- 1穴パンチでリングホールの穴をあける(ゴミ貯めの蓋を外し, パンチの穴の裏側からのぞき, 印刷の黒丸がちょうど真ん中に来るところで穴をあける).
- 型紙に沿ってクリアファイルを切り抜く. 同じ場所にカッターの刃を3回くらい引くイメージで軽く引くとよい. 深く切るよりも固定している定規などが動かないようにする方を意識するとうまくいく気がする.
- 切り抜いた後に角を丸めておくと仕上がりがよい. カドマルとかを使ってもいいけどハサミでちょいちょいっと丸めても大した手間ではない.
- 差込部分を差し込む前に完成形を想定して折り目をつけておく(台形の底辺のところを折り曲げる). 折り曲げる方向を間違えないように要注意!!! 折り曲げる方向は下の完成形の写真を参考に.
- 差し込む際には, 差込部分の台形の両端のうち, 端に近い方を先に全部差し込んでから残りを無理やり差し込む感じにすると差込み易い(写真でいうと上の差込口は上の部分から, 下の差込口は下の部分から先に差し込むとよい).
完成!!!
5. まとめ
pros(いいところ):
- 使うペンに合わせてぴったりのものが作れる
- 道具しだいかもしれないけど, 作るのが簡単
- 透明のクリアファイルを使うとホルダーが目立たない
- クリアファイル製なので薄くて軽い
cons(いまいちなところ):
- 耐久性が低そう(特に千枚通しで穴をあけたあたりが裂けそう). ちょこちょこテープで補強しながら使うとか, ある意味経年変化が楽しめるので人によっては悪くないかも.
- とにかくチープ感がすごい(個人的にはその方が好みかも)
- なんとなく新品のクリアファイルがもったいなくて汚い使い古しのファイルで作って, 出来上がりもきたない感じになりがち(私だけか)
Discussion