📧

mu-citeで引用部分の署名を削除する設定(Gnus/Mew/Wanderlust)

2022/10/21に公開約7,400字

概要

mu-citeはEmacs用メーラー・ニュースリーダーのための引用ツールです。入手先は複数ありますが私はMELPAからインストールしました。一般的にメールへのリプライやネットニュース記事へのフォローアップの際は不要な部分は削除して引用すべきだと言われてきました(最近メールでは全文引用することも多いようですが)。大抵の場合署名も引用は不要です。この記事ではGnus/Mew/Wanderlustでmu-citeを使って引用部分の署名を削除する設定を紹介します。

更新情報

削除できる結語にAll the best,を追加。(2022/10/28)

この設定で引用部分に対してできること

  • 本文と署名の区切りである改行+-- +改行以降を削除。
  • 英文メールなどにある空行+Regards,+改行のような結語以降を削除。
  • 引用するメッセージのFrom: と同じ名前やメールアドレスが末尾にあれば削除。アルファベットでファーストネーム(+ミドルネーム)+ラストネームの場合ファーストネームだけでも可。ただしメールアドレスだけなら削除しない。
  • 冒頭と末尾の空行を削除。

この設定を使うべきでない場合

  • 署名の後の引用・追伸・他の情報を引用したい。
  • foo> のような識別子付き引用符を使いたい。
  • Mewでメッセージ作成時に引用部分に色が付いてほしい。

動作確認環境

Gnus用

.emacs
(autoload 'mu-cite-original "mu-cite" nil t)
(setq message-cite-function #'mu-cite-original)
.gnus.el
(setq mu-cite-prefix-format '("> "))
(setq mu-cite-cited-prefix-regexp "^[^[:blank:]\n<>]+>+[[:blank:]]*")
(setq mu-cite-top-format '(from " writes:\n\n"))

(defun strip-signature (regexp &optional replacement)
  (or replacement (setq replacement ""))
  (goto-char (point-min))
  (while (re-search-forward regexp nil t)
    (replace-match replacement)))

(defun my-mu-cite-hook-function ()
  (save-excursion
    (goto-char (point-min))
    (re-search-forward "^\\(\n-- \n\\(.*\n\\)*\\)" nil t)
    (let ((my-signature (match-string 1)))
      (dolist (e '(("^\n-- \n\\(.*\n\\)*")
                   ("^\\([^[:blank:]\n<>]+>.*\\)" "> \\1")
                   ("^\\([^\n>].+\n\n\\)\\(>[>[:blank:]]+\n\\)+" "\\1")
                   ("^> >" ">>")
                   ("^> -- \n\\(>.*\n\\)*")
                   ("^\\(>[[:blank:]]+\n\\)+> \\(\\(all the \\)?best\
\\( regards\\| wishes\\)?\\|cheers\\|\\(good\\)?bye\\|good luck\\|\
\\(kind \\|warm\\(est\\)? \\)?regards\\|respectfully\\|\\(yours \
\\)?sincerely\\( yours\\)?\\|thank you\\( very much\\)?\\|\\(many \
\\)?thanks\\( in advance\\| very much\\)?\\),[[:blank:]]*\n\\(>.*\n\\)*")))
        (strip-signature (car e) (cadr e)))                
      (goto-char (point-min))
      (when (re-search-forward "^\"?\\([^[:blank:]\n<>\"]+\\)\
\\([^\n<>\"]+\\)?\"? <\\([^\n<>\"]+\\)> writes:" nil t)
        (let ((first-name (match-string 1))
              (middle-last-name (or (match-string 2) ""))
              (mail-address (match-string 3)))
          (strip-signature (apply #'format "^>\
[[:blank:]]*\\(-+[[:blank:]]*\\)?%s\\(%s\\)?\\([[:blank:]]*\\(\n>\
[[:blank:]]+\\)*<?%s>?\\)?[[:blank:]]*\n\\(>[>[:blank:]]+\n\\)*\\'\
" (mapcar #'regexp-quote (list first-name middle-last-name mail-address))))))
      (strip-signature "^\\(>[>[:blank:]]+\n\\)+\\'")             
      (goto-char (point-max))
      (ignore-errors (insert my-signature)))))

(add-hook 'mu-cite-post-cite-hook #'my-mu-cite-hook-function)

Mew用

.emacs
(autoload 'mu-cite-original "mu-cite" nil t)
(add-hook 'mew-cite-hook #'mu-cite-original)
.mew.el
(setq mu-cite-prefix-format '("> "))
(setq mu-cite-cited-prefix-regexp "^[^[:blank:]\n<>]+>+[[:blank:]]*")
(setq mu-cite-top-format
      '("From: " from "\nSubject: " subject "\nDate: " date "\n\n"))

(defun strip-signature (regexp &optional replacement)
  (or replacement (setq replacement ""))
  (goto-char (point-min))
  (while (re-search-forward regexp nil t)
    (replace-match replacement)))

(defun my-mu-cite-hook-function ()
  (save-excursion
    (dolist (e '(("^\\([^[:blank:]\n<>]+>.*\\)" "> \\1")
                 ("^\\([^\n>].+\n\n\\)\\(>[>[:blank:]]+\n\\)+" "\\1")
                 ("^> >" ">>")
                 ("^> -- \n\\(>.*\n\\)*")
                 ("^\\(>[[:blank:]]+\n\\)+> \\(\\(all the \\)?best\
\\( regards\\| wishes\\)?\\|cheers\\|\\(good\\)?bye\\|good luck\\|\
\\(kind \\|warm\\(est\\)? \\)?regards\\|respectfully\\|\\(yours \
\\)?sincerely\\( yours\\)?\\|thank you\\( very much\\)?\\|\\(many \
\\)?thanks\\( in advance\\| very much\\)?\\),[[:blank:]]*\n\\(>.*\n\\)*")))
      (strip-signature (car e) (cadr e)))                
    (goto-char (point-min))
    (when (re-search-forward "^----\nfrom: \"?\\([^[:blank:]\n<>\"]+\\)\
\\([^\n<>\"]+\\)?\"? <\\([^\n<>\"]+\\)>" nil t)
      (let ((first-name (match-string 1))
            (middle-last-name (or (match-string 2) ""))
            (mail-address (match-string 3)))
        (strip-signature (apply #'format "^>\
[[:blank:]]*\\(-+[[:blank:]]*\\)?%s\\(%s\\)?\\([[:blank:]]*\\(\n>\
[[:blank:]]+\\)*<?%s>?\\)?[[:blank:]]*\n\\(>[>[:blank:]]+\n\\)*\\'\
" (mapcar #'regexp-quote (list first-name middle-last-name mail-address))))))
    (strip-signature "^\\(>[>[:blank:]]+\n\\)+\\'")))             

(add-hook 'mu-cite-post-cite-hook #'my-mu-cite-hook-function)

Wanderlust用

.emacs
(autoload 'mu-cite-original "mu-cite" nil t)
(add-hook 'mail-citation-hook #'mu-cite-original)
.wl
(setq mu-cite-prefix-format '("> "))
(setq mu-cite-cited-prefix-regexp "^[^[:blank:]\n<>]+>+[[:blank:]]*")
(setq mu-cite-top-format '("On " date ",\n" from " wrote:\n\n"))

(defun strip-signature (regexp &optional replacement)
  (or replacement (setq replacement ""))
  (goto-char (point-min))
  (while (re-search-forward regexp nil t)
    (replace-match replacement)))

(defun my-mu-cite-hook-function ()
  (save-excursion
    (dolist (e '(("^\\([^[:blank:]\n<>]+>.*\\)" "> \\1")
                 ("^\\([^\n>].+\n\n\\)\\(>[>[:blank:]]+\n\\)+" "\\1")
                 ("^> -- \n\\(>.*\n\\)*")
                 ("^\\(>[[:blank:]]+\n\\)+> \\(\\(all the \\)?best\
\\( regards\\| wishes\\)?\\|cheers\\|\\(good\\)?bye\\|good luck\\|\
\\(kind \\|warm\\(est\\)? \\)?regards\\|respectfully\\|\\(yours \
\\)?sincerely\\( yours\\)?\\|thank you\\( very much\\)?\\|\\(many \
\\)?thanks\\( in advance\\| very much\\)?\\),[[:blank:]]*\n\\(>.*\n\\)*")))
      (strip-signature (car e) (cadr e)))                
    (goto-char (point-min))
    (when (re-search-forward "^\"?\\([^[:blank:]\n<>\"]+\\)\
\\([^\n<>\"]+\\)?\"? <\\([^\n<>\"]+\\)> wrote:" nil t)
      (let ((first-name (match-string 1))
            (middle-last-name (or (match-string 2) ""))
            (mail-address (match-string 3)))
        (strip-signature (apply #'format "^>\
[[:blank:]]*\\(-+[[:blank:]]*\\)?%s\\(%s\\)?\\([[:blank:]]*\\(\n>\
[[:blank:]]+\\)*<?%s>?\\)?[[:blank:]]*\n\\(>[>[:blank:]]+\n\\)*\\'\
" (mapcar #'regexp-quote (list first-name middle-last-name mail-address))))))
    (strip-signature "^\\(>[>[:blank:]]+\n\\)+\\'")             
    (strip-signature "\\(^[^\n<>]+\\)\\( <[^\n<>]+>\\)?\\( wrote:+\n\\)"
                     "\\1\\3> ")))

(add-hook 'mu-cite-post-cite-hook #'my-mu-cite-hook-function)

参考

https://melpa.org/#/mu-cite
https://mew.org/ml-archives/mew-dist/2004-August/024815.html
https://wanderlust.github.io/wl-docs/wl-ja.html#mu_002dcite
https://pc11.5ch.net/test/read.cgi/unix/1114097161/
http://roguelife.org/~tsumura/emacs/mu-cite.html
https://ayatakesi.github.io/lispref/28.2/elisp-ja.html

謝辞

この記事をこのページにまとめるまでに次の方々から助言をいただきました。

本当にありがとうございます。

Discussion

ログインするとコメントできます