Zig で OS in 1,000 Lines をやる

const std = @import("std");

pub fn build(b: *std.Build) void {
    const features = std.Target.riscv.Feature;
    var disabled_features = std.Target.Cpu.Feature.Set.empty;
    var enabled_features = std.Target.Cpu.Feature.Set.empty;

    disabled_features.addFeature(@intFromEnum(features.a));
    disabled_features.addFeature(@intFromEnum(features.d));
    disabled_features.addFeature(@intFromEnum(features.e));
    disabled_features.addFeature(@intFromEnum(features.f));
    disabled_features.addFeature(@intFromEnum(features.c));
    enabled_features.addFeature(@intFromEnum(features.m));

    const target = b.resolveTargetQuery(.{
        .cpu_arch = .riscv32,
        .os_tag = .freestanding,
        .abi = .none,
        .ofmt = .elf,
        .cpu_features_sub = disabled_features,
        .cpu_features_add = enabled_features,
    });
    const optimize = b.standardOptimizeOption(.{});

    const kernel = b.addExecutable(.{
        .name = "kernel.elf",
        .root_source_file = b.path("src/kernel.zig"),
        .target = target,
        .optimize = optimize,
    });

    kernel.entry = .{ .symbol_name = "boot" };
    kernel.setLinkerScript(b.path("kernel.ld"));
    b.installArtifact(kernel);

    const kernel_step = b.step("kernel", "Build the kernel");
    kernel_step.dependOn(&kernel.step);

    const qemu_cmd = b.addSystemCommand(&.{
        "qemu-system-riscv32",
        "-machine",
        "virt",
        "-bios",
        "default",
        "-nographic",
        "-serial",
        "mon:stdio",
        "--no-reboot",
        "-kernel",
        b.getInstallPath(.bin, kernel.name),
    });
    qemu_cmd.step.dependOn(b.getInstallStep());

    const run_step = b.step("run", "Run the kernel on QEMU");
    run_step.dependOn(&qemu_cmd.step);
}

kernel.entry = .{ .symbol_name = "boot" };

extern var __bss: u8;
extern var __bss_end: u8;
extern var __stack_top: u8;

pub export fn kernel_main() callconv(.C) noreturn {
    const start = @intFromPtr(&__bss);
    const end = @intFromPtr(&__bss_end);
    const len: usize = end - start;

    const bss_ptr: [*]u8 = @ptrFromInt(start);
    @memset(bss_ptr[0..len], 0);

    while (true) {}
}

pub export fn boot() linksection(".text.boot") callconv(.naked) noreturn {
    asm volatile (
        \\ mv sp, %[stack]
        \\ j kernel_main
        :
        : [stack] "r" (&__stack_top),
        : "memory"
    );
}

pub fn syscall1(number: usize, arg1: usize) usize {
    // インラインアセンブリは「値を返す式」です。
    // `asm` キーワードで式が始まります。
    return asm
    // `volatile` は任意指定で、「このインラインアセンブリ式には副作用がある」
    // ことを Zig に伝えます。`volatile` がない場合、式の結果が使われなければ
    // Zig はインラインアセンブリを削除してよいことになります。
    volatile (
    // 次はコンパイル時文字列で、これがアセンブリコードです。
    // この文字列の中では、レジスタが期待される場所で `%[ret]`、`%[number]`、
    // `%[arg1]` を使って、引数や戻り値に Zig が用いるレジスタを指定できます
    // （レジスタ制約文字列を使う場合）。ただし、この下のコードでは使っていません。
    // リテラルの `%` が欲しい場合は `%%` と二重にしてエスケープします。
    // ここでは複数行文字列リテラルが便利なことが多いです。
        \\syscall
        // 次は出力です。将来的に Zig が複数出力に対応する可能性があります
        // （https://github.com/ziglang/zig/issues/215 の解決次第）。
        // 出力が 1 つもないことも認められており、その場合このコロンの直後に
        // 入力のためのコロンが来ます。
        :
        // これは上のアセンブリ文字列内で `%[ret]` 構文に使われる名前を指定します。
        // この例では使っていませんが、構文としては必須です。
          [ret]
          // 次は出力制約文字列です。この機能は Zig ではまだ不安定扱いなので、
          // その意味づけは LLVM/GCC のドキュメントを参照してください。
          // http://releases.llvm.org/10.0.0/docs/LangRef.html#inline-asm-constraint-string
          // https://gcc.gnu.org/onlinedocs/gcc/Extended-Asm.html
          // この例では制約文字列は「このインラインアセンブリの結果は $rax にある」
          // ことを意味します。
          "={rax}"
          // 次は値バインディング、または `->` に続く型のどちらかです。
          // 型を置く場合は、その型がインラインアセンブリ式の結果型です。
          // 値バインディングの場合は `%[ret]` 構文で、その値に結びつけられた
          // レジスタを参照できます。
          (-> usize),
          // 次は入力のリストです。
          // これらの入力に対する制約は「アセンブリが実行される時点で
          // $rax には `number` の値、$rdi には `arg1` の値が入っていること」
          // を意味します。入力パラメータの数は任意（ゼロも可）です。
        : [number] "{rax}" (number),
          [arg1] "{rdi}" (arg1),
          // 次はクロバー（clobbers）のリストです。これは、このアセンブリの実行で
          // 値が保持されないレジスタの集合を宣言します。
          // 出力や入力のレジスタは含みません。特別なクロバー値 "memory" は、
          // このアセンブリが宣言されていない任意のメモリ位置に書き込む可能性がある
          // ことを意味します（宣言済みの間接出力の指すメモリに限らない、ということ）。
          // この例では、カーネルの syscall が $rcx と $r11 を保存しないことが
          // 知られているため、それらを列挙しています。
        : .{ .rcx = true, .r11 = true });
}