そろそろShaderをやるパート27 波動方程式とCustomRenderTextureで波紋を描画

5 min読了の目安(約4900字TECH技術記事

そろそろShaderをやります

そろそろShaderをやります。そろそろShaderをやりたいからです。
パート100までダラダラ頑張ります。10年かかってもいいのでやります。
100記事分くらい学べば私レベルの初心者でもまあまあ理解できるかなと思っています。

という感じでやってます。

※初心者がメモレベルで記録するので
 技術記事としてはお力になれないかもしれません。

下準備

下記参考
そろそろShaderをやるパート1 Unite 2017の動画を見る(基礎知識~フラグメントシェーダーで色を変える)

デモ

ちょろっとInspectorを操作する必要がありますが、確認できました。

CustomRenderTexture

CustomできるRenderTextureらしいです。

まずRenderTextureってなんだっけ?ってなったので調べました。

下記のように記述がありました。
【引用元】:Render Texture

A Render Texture is a type of Texture that Unity creates and updates at run time.

使い道はいろいろあるようです。
カメラの描画結果を映してサブモニターにしたり、
動画を貼り付けてスクリーンとして使ったりできるようです。

CustomRenderTextureに話を戻すと、
そのRenderTextureを拡張できるってことです。

Textureの描画処理をShaderで拡張できるので、
複雑な計算処理を施したTextureの使用が可能になるようです。

【参考リンク】: CustomRenderTextureを使って波紋エフェクトを作る

Shaderサンプル

まずはCustomRenderTexture側で使用するShaderです。

Shader "Custom/CustomRenderRipple"
{
    Properties
    {
        _S2("PhaseVelocity^2", Range(0.0, 0.5)) = 0.2
        _Attenuation("Attenuation", Range(0.0, 1.0)) = 0.999
        _DeltaUV("Delta UV", Float) = 0.1
    }

    SubShader
    {
        Pass
        {
            CGPROGRAM
            #pragma vertex CustomRenderTextureVertexShader //専用の定義済みvertexシェーダ関数
            #pragma fragment frag

            #include "UnityCustomRenderTexture.cginc" //専用のcgincファイル

            half _S2;
            half _Attenuation;
            float _DeltaUV;
            sampler2D _MainTex;

            float4 frag(v2f_customrendertexture i) : SV_Target
            {
                float2 uv = i.globalTexcoord;

                // 1pxあたりの単位を計算する
                float du = 1.0 / _CustomRenderTextureWidth;
                float dv = 1.0 / _CustomRenderTextureHeight;
                float2 duv = float2(du, dv) * _DeltaUV;

                // 現在の位置のテクセルをフェッチ
                float2 c = tex2D(_SelfTexture2D, uv);

                //波動方程式
                //h(t + 1) = 2h + c(h(x + 1) + h(x - 1) + h(y + 1) + h(y - 1) - 4h) - h(t - 1)
                //今回、h(t + 1)は次のフレームでの波の高さを表す
                //R,Gをそれぞれ高さとして使用
                float k = (2.0 * c.r) - c.g; //2h - h(t - 1) を先に計算
                float p = (k + _S2 * ( //_S2は係数 位相の変化する速度
                    tex2D(_SelfTexture2D, uv + duv.x).r +
                    tex2D(_SelfTexture2D, uv - duv.x).r +
                    tex2D(_SelfTexture2D, uv + duv.y).r +
                    tex2D(_SelfTexture2D, uv - duv.y).r - 4.0 * c.r)
                ) * _Attenuation; //減衰係数

                // 現在の状態をテクスチャのR成分に、ひとつ前の(過去の)状態をG成分に書き込む。
                return float4(p, c.r, 0, 0);
            }
            ENDCG
        }
    }
}

偉大なる下記参考リンクのまんまなのですが、
CustomRenderTexture用のcgincが用意されており、
それを使用することでRenderTextureを拡張できます。
細かい設定も下記リンクに丁寧に載っているので割愛します。

【参考リンク】: CustomRenderTextureを使って波紋エフェクトを作る

波動方程式に関しては、下記動画を一万回くらい観れば理解できると思います。
私は5000回ほど観て理解したつもりの状態で先に進むことにしました。

【Unite 2017 Tokyo】スマートフォンでどこまでできる?3Dゲームをぐりぐり動かすテクニック講座

CustomRenderTextureをマテリアルのTextureとして使用する

先ほど作成したCustomRenderTextureをマテリアルのTextureとして使用します。
フラグメントシェーダーでTextureとして扱うだけなので、とってもシンプルです。

Shaderサンプル

Shader "Custom/RippleSimulation"
{
    Properties
    {
        _CustomRendererTex("Custom Renderer Texture", 2D) = "gray" {}
    }

    SubShader
    {
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            sampler2D _CustomRendererTex;
            
            v2f vert(appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;
                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                //カスタムレンダーテクスチャーのピクセル情報を使用
                return tex2D(_CustomRendererTex, i.uv);
            }
            ENDCG
        }
    }
}

あとは上記Shaderを適用したマテリアルをPlaneに設定すればOKです。

参考リンク

水面を作ってみた
CustomRenderTexture
Unity 2017.1 の機能の CustomRenderTexture を使ってみた
【Unite 2017 Tokyo】スマートフォンでどこまでできる?3Dゲームをぐりぐり動かすテクニック講座
WaveShooter