MS-DOSのEXEフォーマット形式のサンプルコード

Hello, World!を表示するプログラム

	ASSUME	CS:CODE,DS:DATA,SS:STACK

STACK   SEGMENT STACK
	db	123h dup(?)
STACK   ENDS

DATA    SEGMENT
MSG	db	"Hello, World!",0dh,0ah,'$'
DATA    ENDS

CODE    SEGMENT
START:
	mov	ax, DATA
	mov	ds, ax
	;文字出力
	mov	ah, 09h
	mov	dx, offset MSG
	int	21h
	;終了
	mov	ax, 4c00h
	int	21h
CODE    ENDS

	END	START

EXE形式ファイルのアセンブル＆リンク

JWASMR -mz -Fo hello.exe hello.asm

COMファイルは28バイト程度でしたが、このEXEファイルは385バイトになりました。
セグメントをSTACK、DATA、CODEの順に書きましたが、それが原因で、ファイルの先頭の方にSTACKの領域の分がファイルに埋め込まれました。

セグメントの順番を変えてみる

	ASSUME	CS:CODE,DS:DATA,SS:STACK

CODE    SEGMENT
START:
	mov	ax, DATA
	mov	ds, ax
	;文字出力
	mov	ah, 09h
	mov	dx, offset MSG
	int	21h
	;終了
	mov	ax, 4c00h
	int	21h
CODE    ENDS

DATA    SEGMENT
MSG	db	"Hello, World!",0dh,0ah,'$'
DATA    ENDS

STACK   SEGMENT STACK
	db	123h dup(?)
STACK   ENDS

	END	START

スタックセグメントの定義を最後にしてみました。

MZ形式EXEファイルのヘッダー情報

|Offset|名称|Size|説明|
|----|----|----|----|----|
|0:0x00|Signature|word|0x5A4D（「M」および「Z」のASCII）ファイルが有効なEXE形式のファイルで有る事を示す為に付けられた署名|
|2:0x02|Extra bytes|word|最後のページに入っているバイト数。|
|4:0x04|Pages|word|全体/部分ページの数。５１２バイト単位のヘッダも含むファイルの大きさ|
|6:0x06|Relocation items|word|リロケーションテーブルのエントリ数。|
|8:0x08|Header size|word|ヘッダーのサイズ（１６バイト単位）。|
|10:0x0A|Minimum allocation|word|PSPとプログラムイメージを除く、プログラムに必要な段落数。十分な大きさの空きブロックがない場合、ロードは停止します。|
|12:0x0C|Maximum allocation|word|プログラムによって要求された段落の数。十分な大きさの空きブロックがない場合は、可能な最大のブロックが割り当てられます。|
|14:0x0E|Initial SS|word|SSにセットする再配置可能なセグメントアドレス。|
|16:0x10|Initial SP|word|SPの初期値。|
|18:0x12|Checksum|word|ファイル内の他のすべての単語の合計に追加すると、結果はゼロになります。|
|20:0x14|Initial IP|word|IPの初期値。|
|22:0x16|Initial CS|word|CSにセットする再配置可能セグメントアドレス。|
|24:0x18|Relocation table|word|再配置テーブルへの（絶対）オフセット。|
|26:0x1A|Overlay|word|オーバーレイ管理に使用される値。ゼロの場合、これがメインの実行可能ファイルです。|
|28:0x1C|Overlay information|N/A|ファイルには、メインのプログラムオーバーレイ管理に関する追加情報が含まれている場合があります。|
このヘッダー情報はMS-DOSで使用されている領域です。WindowsのEXEファイルにも存在しますが、この情報が使われる事はありません。正確には、Windowsでは先頭のSignatureと以下で表すPE形式EXEファイルの追加情報の最後の項目のみを使用しているようです。

PE形式EXEファイル追加情報

|Offset|名称|Size|説明|
|----|----|----|----|----|
|28:0x1C|Reserved|qword||
|36:0x24|OEM identifier|word|名前で定義されていますが、他の情報は提供されていません。通常はゼロ|
|38:0x26|OEM info|word|名前で定義されていますが、他の情報は提供されていません。通常はゼロ|
|40:0x28|Reserved|20 bytes|
|50:0x3C|PE header start|dword| PEヘッダーの開始アドレス|

Windowsで作成したEXEファイルの先頭部分

PE header start(3Ch)の情報を見るとF0hがセットされている事が分かります。F0hアドレスを見るとアスキーコードでPEがセットされています。WindowsではF0h以前の部分は無視されますが、MS-DOSではMS-DOSヘッダー情報とMS-DOSリアルモードスタブプログラムと言われる部分を実行して終了します。
PE形式EXEをMS-DOSで実行したときの動作は以下のようになります。

	push	cs
	pop	ds
	mov	dx, 000eh
	mov	ah, 09h
	int	21h
	mov	ax, 4c01h
	int	21h

000Ehはバイナリエディタで見たときの0000004Ehを指しています。This program cannot be run in DOS mode.がメモリに展開されたときの先頭文字のオフセットアドレスです。
COM形式のプログラムのインストラクションポインタはORG 100Hを最初に宣言してるので100から始まりますが、EXE形式のプログラムのインストラクションポインタは0から始まります。ややこしい話しですが、COM形式の場合はバイナリエディタで見たアドレスと比較してメモリ上のオフセットアドレスはプラス100すると一致しますが、EXE形式の場合はDOSヘッダー情報の分だけマイナスすると一致します。

簡略化セグメントで記述

	.model	small
	.stack
	.data

MSG	db	"Hello, World!",0dh,0ah,'$'

	.code
	.startup
	;文字列出力
	mov	ah, 09h
	mov	dx, offset MSG
	int	21h
	;終了
	.exit	00h

END

簡略化セグメントのメモリモデル

オプション

簡略化セグメントの種類