⏳

TerraformでIAMロールを作成する際に初回だけエラーになる時のTips

に公開
2025/09/02
2件

こんにちは、ツクリンクでSREエンジニアをやってるida.です。

TerraformでIAMロールとそれをアタッチするリソースを同時に作成する際、初回だけエラーになったことはありませんか?
でも2回目以降は成功するので、常設環境の場合はrerunで回避して「結局なんだったんだろう...」ということもあるかと思います。
常設環境は大した問題にならない可能性もありますが、都度構築しては削除するような環境では運用面で課題になってきます。

今回はその原因と対処法について、実際の経験をもとに解説しようと思います。

事象について

私がこの事象に陥ったケースは以下2つのリソースを作成する時でした。
もちろん他にもまだまだ存在すると思います。

  • Bedrockエージェントを作成し、それに紐づくIAMロールも同時に作成した時
  • SESの設定セットでイベント送信先をAmazon Kinesis Data Firehoseとしてリソースを作成し、それに紐付けるIAMロールも同時に作成した時

例えば以下のようなリソース作成で発生します。

# IAMロールの作成
resource "aws_iam_role" "bedrock_agent_role" {
  name = "BedrockAgentRole"
  
  assume_role_policy = jsonencode({
    Version = "2012-10-17"
    Statement = [{
      Action = "sts:AssumeRole"
      Effect = "Allow"
      Principal = {
        Service = "bedrock.amazonaws.com"
      }
      # ... 必要な条件を記載 ...
    }]
  })
}

# IAMロールにアタッチするポリシーの作成
resource "aws_iam_policy" "bedrock_agent_policy" {
  name = "BedrockAgentPolicy"
  
  policy = jsonencode({
    Version = "2012-10-17"
    Statement = [{
      Effect = "Allow"
      Action = [
        "bedrock:InvokeModel",
        "bedrock:InvokeAgent",
        # ... Bedrockに必要な権限を記載 ...
      ]
      Resource = "*"
    }]
  })
}

# IAMロールにポリシーをアタッチ
resource "aws_iam_role_policy_attachment" "bedrock_agent_policy_attachment" {
  role       = aws_iam_role.bedrock_agent_role.name
  policy_arn = aws_iam_policy.bedrock_agent_policy.arn
}

# Bedrockエージェントの作成
resource "aws_bedrockagent_agent" "example_agent" {
  agent_name                  = "example-agent"
  agent_resource_role_arn     = aws_iam_role.bedrock_agent_role.arn
  foundation_model            = "arn:aws:bedrock:ap-northeast-1:accountID:inference-profile/apac.anthropic.claude-3-7-sonnet-20250219-v1:0"
}

この構成でterraform applyを実行すると、以下のようなエラーが発生することがあります。
(作成するリソース毎にエラー文言は異なります。)

Error: creating Bedrock Agent
│ 
│   with aws_bedrockagent_agent.example_agent,
│   on main.tf line 25, in resource "aws_bedrockagent_agent" "example_agent":
│   25: resource "aws_bedrockagent_agent" "example_agent" {
│ 
│ operation error Bedrock Agent: CreateAgent, https response error StatusCode: 403, RequestID:
│ XXXXXXXX-XXXX-XXXX-XXXX-XXXXXXXXXXXX, AccessDeniedException: Access denied while trying to create/update an agent using
│ InferenceProfile arn:aws:bedrock:ap-northeast-1:accountID:inference-profile/apac.anthropic.claude-3-7-sonnet-20250219-v1:0.
│ Ensure Agent role has valid permissions to use the inference profile.

原因と対策

原因

原因自体は単純で、TerraformがIAMポリシーの作成・アタッチメントは完了したと認識しても、AWS内部での権限の伝播(propagation)が完了していないためです。つまり、ポリシーは作成されているが権限が有効になっていない状態でリソースの作成処理に入ってしまい、「(ポリシーで定義しているはずの)権限がない」というエラーが発生します。

TerraformではAWSからの応答をもってポリシーの作成が完了したと認識しているので、depends_onを単純に追加しても同じ問題で解消されません。これはAWS側でのポリシーの伝播(propagation)に時間がかかることが原因です。

対策

対策としてはTerraformのtime_sleepリソースを利用します。
IAMポリシーのアタッチメント完了とIAMロールを利用するリソースの作成の間にtime_sleepを入れて意図的に待機時間を作ります。ちょっと古典的な手法かと思いますが、現状これが一番確実で実用的だと感じています。

対策を適用したリソースは以下のようになります:

# IAMロールの作成
resource "aws_iam_role" "bedrock_agent_role" {
  name = "BedrockAgentRole"
  
  assume_role_policy = jsonencode({
    Version = "2012-10-17"
    Statement = [{
      Action = "sts:AssumeRole"
      Effect = "Allow"
      Principal = {
        Service = "bedrock.amazonaws.com"
      }
      # ... 必要な条件を記載 ...
    }]
  })
}

# IAMロールにアタッチするポリシーの作成
resource "aws_iam_policy" "bedrock_agent_policy" {
  name = "BedrockAgentPolicy"
  
  policy = jsonencode({
    Version = "2012-10-17"
    Statement = [{
      Effect = "Allow"
      Action = [
        "bedrock:InvokeModel",
        "bedrock:InvokeAgent",
        # ... Bedrockに必要な権限を記載 ...
      ]
      Resource = "*"
    }]
  })
}

# IAMロールにポリシーをアタッチ
resource "aws_iam_role_policy_attachment" "bedrock_agent_policy_attachment" {
  role       = aws_iam_role.bedrock_agent_role.name
  policy_arn = aws_iam_policy.bedrock_agent_policy.arn
}

# NOTE: IAMポリシーのアタッチメント完了後一定期間をおかないとBedrockエージェントにアタッチできず起動エラーになる。
# そのため明示的に60秒待ってから作成するようにする
resource "time_sleep" "wait_iam_bedrock_agent_role" {
  create_duration = "60s"

  depends_on = [aws_iam_role_policy_attachment.bedrock_agent_policy_attachment]
}

# Bedrockエージェントの作成
resource "aws_bedrockagent_agent" "example_agent" {
  agent_name                  = "example-agent"
  agent_resource_role_arn     = aws_iam_role.bedrock_agent_role.arn
  foundation_model            = "arn:aws:bedrock:ap-northeast-1:accountID:inference-profile/apac.anthropic.claude-3-7-sonnet-20250219-v1:0"

  depends_on = [
    time_sleep.wait_iam_bedrock_agent_role
  ]
}

このコードではIAMロールとポリシーのアタッチメントが完了した後、60秒間待機します。
待機後にBedrockエージェントを作成し始めるので、その頃にはポリシーの権限も完全に伝播しており、正常に紐づけることができます。

運用での効果

ツクリンクではプレビュー環境という都度利用の環境がありますが、この対策を実装して以降この問題が発生したことはありません。
60秒から短くすることも可能かと思いますが、ギリギリを攻めるとFLAKY(不安定)になりそうなので、余裕をもってこの設定にしています。

おわりに

今回はTerraformでIAMロール(ポリシー)の作成時に発生する初回エラーの原因と対処法について紹介しました。

この問題は、AWSのIAM伝播の仕組みを理解していないと「なぜ2回目は成功するのか?」が分からず、根本的な解決に至らないことが多いです。time_sleepを使った対策は古典的ではありますが、確実で運用しやすい手法だと感じています。

Infrastructure as Codeでの環境構築では、このような細かな問題も多々発生します。みなさんもTerraformを使ったインフラ構築で同様の問題に遭遇した際は、ぜひこの方法を試してみてください。

Discussion

rakiraki

たぶん間違ってる。
IAM Role の作成はコード的に終わってるけど、権限がないってエラーになっている(そう書いてある)ので、終わっていないのはアタッチだけ。

aws_iam_role <- aws_bedrockagent_agent
↑
aws_iam_role_policy_attachment <- aws_iam_policy

ってゆうリソースアドレスの連携構造なので、 role ができたら agent の作成に入ってしまうので(アタッチが終わってないので)エラー(権限エラー)になる。

aws_bedrockagent_agent の depends_on には sleep ではなく aws_iam_role_policy_attachment.bedrock_agent_policy_attachment を入れるのが正解だと思う。

1
ida.ida.

コメントありがとうございます!
文章がうまく説明できておらず申し訳ございません🙇

おっしゃる通り、ロールの作成というよりかはポリシーのアタッチが完了していないと表現するのが正しいですね。。

ただ、aws_iam_role_policy_attachment.bedrock_agent_policy_attachmentを depends_on に指定しても同様のエラーが発生します。つまりポリシーが適用されるまでを Terraform が認識できていない仕様かと思いますので、sleepは以前として必要だと認識しております。
(念の為本日再度確認いたしました。)

< 以下で実行した場合も同様のエラーが発生する >

# Bedrockエージェントの作成
resource "aws_bedrockagent_agent" "example_agent" {
  agent_name                  = "example-agent"
  agent_resource_role_arn     = aws_iam_role.bedrock_agent_role.arn
  foundation_model            = "arn:aws:bedrock:ap-northeast-1:accountID:inference-profile/apac.anthropic.claude-3-7-sonnet-20250219-v1:0"

  depends_on = [
    aws_iam_role_policy_attachment.bedrock_agent_policy_attachment
  ]
}

文章の方は説明が足りてないと改めて感じたので更新させていただきます!

1