M5StackとModbus RTUで産業用モーター(オリエンタルモーター)を動かす
一歩進んだハードウェア制御へ
最近は3Dプリンタの普及もあってか、ホビー用のステッピングモーターとドライバも色々入手性が良くなって、Amazonでも便利なセットが売っていたりします。しかし、以下のような状況ではホビー用だと難しいことも多いのではないでしょうか。
- もっと大きくて重いものを動かしたい
- モーターの角度や絶対位置を取得したい
- モーターへの負荷、発熱を意識したい
- 押し当て運転、トルク制御など高度な制御をしたい
- 常設展示などの長期運用でも安心して使いたい
無垢の(?)ステッピングモーターやドライバを改造・拡張してこれらの要件を実現するのもロマンがありますが、「物を動かしたい」というそもそもの要求からは少し外れていて本質ではないところなので、これらに時間を取られるのも気が引けます。
産業用モーターならできる

もし金で解決するという選択肢があるなら、産業用モーターの出番です。先に挙げたような高い負荷に対応していて、角度を取得するエンコーダも内蔵されているものが多くあります。
多くの場合上のAIイメージのようにモーターとドライバがセットで販売されていて、ドライバに信号を送ることで制御できます。メーカーも以下の通り色々。自分はオリエンタルモーターのAZシリーズを展示系の仕事などでよく扱っています。
Modbus RTU on RS485で制御する
メディアアート定番のOSCのように、産業機器も「大体対応してるよね」というプロトコルのスタンダードが色々あります。その中で今回は表題にも書いたModbusRTUというプロトコルで制御する方法について、その導入にあたる動かすところまでを、M5Stackを使った実例を交えて書いていきます。
サンプルの機器構成
モータードライバ AZD-AX+AZシリーズモーター
今回の構成では、オリエンタルモーターのAZD-AX+AZM69M1Cを動かします。AZシリーズはエンコーダが内蔵されているので、脱力して手動で動かしても位置が保存されており、更に電源を落としても位置情報が保存されているというとても便利なモーターです。
M5Stack + W5500 LANモジュール
ModbusRTUは通信経路にRS485を使用することが多いです。M5StackにはRS485で通信するためのユニットがあります
ですが、私自身は上記ユニットを使ったことがなく、LANポートを搭載したこちらのW5500モジュールを使っていたので、こっちベースで話を進めていきます。PCからネット経由で指示を出せたり、DINレールにも取り付けられるようになるので便利。
実践
ドライバとM5Stackを接続する
AZシリーズのモータードライバはRS485の受け口としてRJ45端子がついています。なのでM5Stack側のRS485端子も同様にRJ45を付けてあげれば、一般的なLANケーブルを配線に使うことができます。これはRS485が作動通信方式なので、ツイストペアでLANケーブルが入手性もよく取り回しが良いためだと思われます。システムに有線LANが共存してると、どっちのケーブルか若干わかりづらい…
RJ45端子は8ピンありますが、実際仕様するのは3ピンだけで、 2番GND, 3番TR+, 6番TR- をそれぞれW5500ユニットのGND, A, Bと接続します。

※Nano bananaしたので機器の見た目がだいぶ違ってますが、まぁこういうことです。詳しくは、AZシリーズ取扱説明書(ドライバ編)27pを参照ください。

M5Stack側の実物はこんな感じ。セットでついてくるRS485基板をあとからはんだ付けしています。
ModbusMasterライブラリで通信周りを実装する
Arduino on M5Stack環境ではModbusライブラリのModbusMasterが使用可能です。上記のW5500モジュールでは5ピン、15ピンを使ったSerial2が使用可能なので、明示的にSerial2をMosbusMasterのインスタンスに渡してあげます。
#include <ModbusMaster.h>
ModbusMaster node;
constexpr uint8_t RX_PIN = 5;
constexpr uint8_t TX_PIN = 15;
const int MODBUS_BAUDRATE = 115200;
void setupModbus() {
// シリアル通信を開始
Serial2.begin(MODBUS_BAUDRATE, SERIAL_8E1, RX_PIN, TX_PIN);
// ModbusMasterが使用するシリアルポートと、スレーブIDを指定
node.begin(1, Serial2);
}
Arduinoのシリアル通信はパリティなし、ストップビット1のSERIAL_8N1がデフォルトですが、AZシリーズのデフォルトは偶数パリティ、ストップビット1のSERIAL_8E1なのでこの辺りハマりがちで注意が必要。
Modbusの通信仕様
Modbusに対応した機器は 「レジスタ」 と呼ばれる2バイトのデータ領域を読み書きできるようになっているので、これを各機器の仕様に合わせて読み書きすることで、モータードライバなら位置情報を取得したり、モーターを動かしたりします。
Modbusではこれら読み書きを行う宣言を「ファンクションコード」として下位の機器に送信します。ModbusMasterを使う際は特に意識することはありませんが、例えば三菱のモーターなどは、一つのレジスタへ書き込む時に単一レジスタ書き込み(0x06)は使わず、複数レジスタ書き込み(0x10)のファンクションコードを使ってワード長1のレジスタを書き込まなくてはいけない、という仕様になっているなど変わった決まり事がメーカーごとに存在したりするので、ファンクションコードの存在などは知っておくとハマりにくくなります。
レジスタの読み書き
ModbusMasterで実際にレジスタを読み書きする場合はこんな感じで書きます。
void readHoldingRegister(uint16_t address, int numReg, uint16_t* buffer) {
uint8_t result = node.readHoldingRegisters(address, numReg);
if (result == node.ku8MBSuccess) {
for (int i = 0; i < numReg; i++) {
buffer[i] = node.getResponseBuffer(i);
}
} else {
Serial.printf("[%d]", millis());
Serial.print("Modbus read error at address ");
Serial.print(address, HEX);
Serial.print(": ");
Serial.println(result, HEX);
}
}
void writeMultipleRegisters(uint16_t address, int numReg, uint16_t* values) {
for (int i = 0; i < numReg; i++) {
node.setTransmitBuffer(i, values[i]);
}
uint8_t result = node.writeMultipleRegisters(address, numReg);
if (result != node.ku8MBSuccess) {
Serial.print("Modbus write error at address ");
Serial.print(address, HEX);
Serial.print(": ");
Serial.println(result, HEX);
}
}
それぞれ読み書きするレジスタ長と、実際のデータを配列で渡します。アドレスはレジスタが設置アドレスで、各メーカーのドキュメントなどに載っている情報をもとに指定します。
現在位置を取得する(レジスタ読み出し)
AZシリーズのドライバで現在位置を取得する場合は、以下のように書きます。位置情報は4バイト(32ビット)で返ってくるので、2レジスタ分を読み出して、32ビット長整数として扱います。
int32_t azd_getPosition() {
uint16_t buffer[2] = {0};
readHoldingRegister(0x00CC, 2, buffer);
int32_t ret = (int32_t(buffer[0]) << 16) | uint16_t(buffer[1]);
return ret;
}
ダイレクトデータ運転で駆動する(レジスタ書き込み)
モーターを動かす方法はいくつかありますが、マイコンが上位にある場合はダイレクトデータ運転が便利です。指令位置・速度・加速度・電流などを一括で送信して動かすモードで、基本的な動作はこの機能で指示が可能です。
enum DDD_DriveMode {
ABS_POS = 0x01,
REL_POS_ORDER = 0x02, // 相対位置決め(指令位置基準)
REL_POS_SENSOR = 0x03, // 相対位置決め(検出位置基準)
RUNNING_POS = 0x07, // 連続回転(位置制御)
RUNNING_SPD = 16, // 連続回転(速度制御)
RUNNING_PUSH = 0x11, // 連続回転(押し当て制御)
RUNNING_TORQUE = 0x12, // 連続回転(トルク制御)
// ... 以下略
};
// ダイレクトデータ運転の基本となる関数(配列を作ってModbusで送信する)
void azd_DirectDrive(DDD_DriveMode mode, int32_t position, int32_t speed, int32_t acceleration, int32_t deceleration, int32_t current) {
uint16_t buffer[] = {
0x0000, // 運転データNo
0x0000, // サブ運転データNo
0x0000, // 運転モードの上位ワード(予約)
uint16_t(mode), // 運転モード
uint16_t((position >> 16) & 0xFFFF), // 目標位置(上位ワード)
uint16_t(position & 0xFFFF), // 目標位置(下位ワード)
uint16_t((speed >> 16) & 0xFFFF), // 目標速度(上位ワード)
uint16_t(speed & 0xFFFF), // 目標速度(下位ワード)
uint16_t((acceleration >> 16) & 0xFFFF), // 加速度(上位ワード)
uint16_t(acceleration & 0xFFFF), // 加速度(下位ワード)
uint16_t((deceleration >> 16) & 0xFFFF), // 減速度(上位ワード)
uint16_t(deceleration & 0xFFFF), // 減速度(下位ワード)
uint16_t((current >> 16) & 0xFFFF), // 目標電流(上位ワード)
uint16_t(current & 0xFFFF), // 目標電流(下位ワード)
0x0000, // 反映トリガ上位
0x0001, // 反映トリガ下位
};
writeMultipleRegisters(0x0058, 16, buffer);
}
// 絶対位置で指定した場所まで移動する
void azd_absolute_position_drive(int32_t position, int32_t speed, int32_t acceleration, int32_t deceleration, int32_t current)
{
azd_DirectDrive(DDD_DriveMode::ABS_POS, position, speed, acceleration, deceleration, current);
}
// 決められたスピードで回転し続ける
void azd_continuous_drive(int32_t speed, int32_t acc, int32_t dec, int32_t current)
{
azd_DirectDrive(DDD_DriveMode::RUNNING_SPD, 0, speed, acc, dec, current);
}
他にも機能いろいろ
とりあえず現在位置を知って、動かすところはこんな感じですが、他にもセンサーを繋いだ原点出し機能、間違って可動域を超えないようにするソフトウェアリミット、アラーム情報の取得とリセットなど本当に色々なコントロールがModbus上からできるようになっています。
今回はとりあえず「動かすところまで」とします。更に詳しい内容はAZシリーズ取扱説明書(機能編)を参照するようにしてみてください。設定可能なレジスタの一覧などもこのドキュメントに全て記載されています。
Discussion