🔍

vibe codingで迷子になったiTermを一発で見つける（Stream Deck＋AppleScript）

に公開
AppleScript
iTerm2
Stream Deck
Vibe Coding
tech

みんなのiTerm迷子になっていません？

Claude Codeを使っていると、複数プロジェクトを並列で動かすため、
プロジェクト分だけの iTerm を開きっぱなしにしている人、結構多いと思います。

自分もそうなのですが、
Claude Codeの作業が終わった
　↓
すぐに確認・返信したい
　↓
でも今どの iTerm にいるか探すのが地味に面倒

という小さなストレスがずっとありました。

そこで
「ボタン一発で、対象の iTerm（プロファイル）を前面に出して、即キーボード操作できる環境」
を作ったところ、快適度が爆上がりしたので共有します。

環境

  • Stream Deck（※スマホ版でも可）
  • macOS
  • iTerm2

対応方法

iTerm2 側の準備

まず、iTerm2 で 専用プロファイルを作成します。

iTerm2 > Settings > Profiles

Claude Code 用など、用途ごとにプロファイルを分けておくと便利です。

  • Colors で背景色を変える
  • Window で背景画像を設定する

などをしておくと、複数 iTerm を開いていても一目で判別できておすすめです。

AppleScript を作成

以下の AppleScript を作成します。
（{新規作成したプロファイル名} は自分の環境に合わせて変更してください）

set targetProfile to "{新規作成したプロファイル名}"

tell application "iTerm"
	activate
	
	set found to false
	set foundWindow to missing value
	set foundTab to missing value
	set foundSession to missing value
	
	repeat with w in windows
		repeat with t in tabs of w
			repeat with s in sessions of t
				try
					if (profile name of s) is targetProfile then
						set found to true
						set foundWindow to w
						set foundTab to t
						set foundSession to s
						exit repeat
					end if
				end try
			end repeat
			if found then exit repeat
		end repeat
		if found then exit repeat
	end repeat
	
	if found then
		-- 前面化
		select foundWindow
		select foundTab
		
		-- ★ここが重要：入力フォーカスを対象セッションへ
		set current session of foundTab to foundSession
		
		-- 念押し（環境によって効く）
		activate
	else
		create window with profile targetProfile
		activate
	end if
end tell

Stream Deck の設定

Stream Deck 側では、

システム > 開く

を選び、
作成した AppleScript を指定するだけです。

動作

設定したボタンを 1回押すだけで、

  • iTerm が起動していない
    → iTerm を起動し、指定プロファイルでウィンドウ作成
  • すでに起動している
    → 対象プロファイルの iTerm が前面に出て、即キーボード操作可能

という挙動になります。

Claude Code から通知が来たら、
とりあえずボタンを押すだけで即操作できるので、
画面を探し回る必要がなくなりました。

おわりに

「いちいち画面を切り替えるのが地味にストレス」
と感じている人には、かなりおすすめです。

また、
「もっとシンプルな方法あるよ」
「こうするとさらに快適になる」

などあれば、ぜひコメントで教えてください 🙌

Discussion